通达信红衣侠女选股公式

请将指标公式改成选股公式

EMA13:=EMA(C,13),COLORWHITE,LINETHICK2;
EMA34:=EMA(C,34),COLORYELLOW;
EMA55:=EMA(C,55),COLORFF00FF;
{EMA120:=EMA(C,120),COLORFFCC66;}
AR1:=EMA55>EMA34 AND EMA34>EMA13;
AR2:=BARSLAST((C-EMA13)/EMA13*100<-6);
AR3:=EMA13>=REF(EMA13,2);
AR4:=COUNT(CROSS(C,EMA13),AR2)=1;
AR5:=AR1 AND AR2 AND AR3 AND AR4;
红杏出墙:AR5 AND FILTER(AR5,10);

请股票高手帮忙做一个“黑客点击”选股公式

HK1:=CROSS(MA(C,13),MA(C,55));{13线上穿55线}
HK2:=C<O;{当日收阴}
HK3:=ABS(L-MA(C,13))<C*0.03 OR ABS(C-MA(C,13))<C*0.04;{收盘价或最低价在13线}
XG:HK1 AND HK2 AND HK3;

(这样即可)

你能给我135战法里面的全部公式吗 股神!

{135战法} {主图}
N :=5;
EMA13:EMA(C,13),COLORWHITE,LINETHICK2;
EMA34:EMA(C,34),COLORYELLOW;
EMA55:EMA(C,55),COLORFF00FF;
EMA120:EMA(C,120),COLORFFCC66;
AR1:=EMA55>EMA34 AND EMA34>EMA13;
AR2:=BARSLAST((C-EMA13)/EMA13*100<-6);
AR3:=EMA13>=REF(EMA13,2);
AR4:=COUNT(CROSS(C,EMA13),AR2)=1;
AR5:=AR1 AND AR2 AND AR3 AND AR4;
AR6:=AR5 AND FILTER(AR5,10);
DRAWTEXT(AR6,L-0.09,'红杏出墙'),COLORYELLOW;
{STICKLINE(AR6,H,L,0.5,1),COLORYELLOW;}
{STICKLINE(AR6,O,C,6,1),LINETHICK2,COLORYELLOW;}
BR1:=COUNT(BETWEEN((C-REF(C,1))/REF(C,1)*100,0,5) ,5)=5;
BR2:=ABS((EMA13-EMA34)+(EMA34-EMA55))/C<0.2;
BR3:=C>EMA55 AND (REF(C,1)<REF(EMA55,1) OR REF(C,2)<REF(EMA55,2) OR REF(C,3)<REF(EMA55,3) OR REF(C,4)<REF(EMA55,4) OR REF
(C,5)<REF(EMA55,5));
BR4:=BR1 AND BR2 AND BR3;
DRAWTEXT(BR4 AND FILTER(BR4,10),L-0.09,'蚂蚁上树'),COLOR00C5FF;
STICKLINE(BR4 AND FILTER(BR4,10),H,L,0.5,1),COLOR00C5FF;
{STICKLINE(BR4 AND FILTER(BR4,10),O,C,6,1),LINETHICK2,COLOR00C5FF;}
CR1:=(C-REF(C,1))/REF(C,1)*100>0.5;
CR2:=V>MA(V,5)*0.6;
CR3:=COUNT(CROSS(EMA13,EMA55),3)=1;
CR4:=ABS(EMA34-EMA55)/EMA55<0.03;
CR5:=EMA55<=EMA120 AND EMA55>=REF(EMA55,1);
CR6:=FILTER(CR1 AND CR2 AND CR3 AND CR4 AND CR5,2);
{STICKLINE(CR6,H,L,0.5,1),COLORF00FF0;}
{STICKLINE(CR6,O,C,6,1),LINETHICK2,COLORF00FF0;}
DRAWTEXT(CR6,L-0.09,'红衣侠女'),COLORF00FF0;
DR1:=EMA13>EMA34 AND EMA34<EMA55;
DR2:=BARSLAST(CROSS(C,EMA55) );
DR3:=H=HHV(H,DR2);
DR4:=BARSLAST(DR3);
DR5:=COUNT(O>C AND C<REF(C,1) AND C>EMA55 AND BETWEEN((C-EMA55)/EMA55,0,0.02),DR4)=1;
DR6:=C>REF(C,1) ;
DR7:= DR1 AND DR5 AND DR6 ;
DR8:=DR7 AND FILTER(DR7 ,10);
DRAWTEXT(DR8,L-0.09,'黑客点击'),COLORD6BA63;
{STICKLINE(DR8,H,L,0.5,1),COLORD6BA63;}
STICKLINE(DR8,O,C,6,1),LINETHICK2,COLORD6BA63;
ER:=BARSLAST(REF(CROSS(EMA55,EMA34),1)) AND CROSS(EMA34,EMA55);
DRAWTEXT(ER,L-0.09,'均线互换'),COLOR0099FF;
{STICKLINE(ER,H,L,0.5,1),COLOR0099FF;}
{STICKLINE(ER,O,C,6,1),LINETHICK2,COLOR0099FF;}
FR:=BARSLAST(REF(CROSS(EMA34,EMA13),1)) AND CROSS(EMA13,EMA34);
DRAWTEXT(FR,L-0.09,'梅开二度'),COLORWHITE;
STICKLINE(FR,H,L,0.5,1),COLORWHITE;
{STICKLINE(FR,O,C,6,1),LINETHICK2,COLORWHITE;}
GR1:=BARSLAST(BETWEEN("BIAS.BIAS2"(6,13,24),0,5) );
GR2:=EMA13>EMA34 AND EMA34>EMA55 AND EMA13>REF(EMA13,1);
GR3:=COUNT("BIAS.BIAS2"(6,13,24)>10 AND H=HHV(H,GR1),GR1);
GR4:=H=HHV(H,GR1);
GR5:="MACD.MACD"(12,26,9)<REF("MACD.MACD"(12,26,9),1);
GR6:=GR2 AND GR3 AND GR4;
GR7:=GR2 AND GR3 AND GR4 AND GR5;
DRAWTEXT(GR6 AND GR7,H+0.13,'见好就收!'),COLOR00FF00;
STICKLINE(GR6 AND GR7,H,H+0.09,4,0),COLOR00FF00;
HR2:=EMA13>=REF(EMA13,3) AND EMA34>=REF(EMA34,1) AND EMA55>=REF(EMA55,1) AND CROSS(C,EMA13) AND CROSS(C,EMA34) AND CROSS
(C,EMA55){ AND CROSS(C,EMA120)};
DRAWTEXT(HR2 AND FILTER(HR2,10),L-0.09,'三线推进'),COLORFFC8FF;
------------------------------
{红杏出墙选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
AR1:=EMA55>EMA34 AND EMA34>EMA13;
AR2:=BARSLAST((C-EMA13)/EMA13*100<-6);
AR3:=EMA13>=REF(EMA13,2);
AR4:=COUNT(CROSS(C,EMA13),AR2)=1;
AR5:=AR1 AND AR2 AND AR3 AND AR4;
红杏出墙:AR5 AND FILTER(AR5,10);
------------------------
{蚂蚁上树选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
BR1:=COUNT(BETWEEN((C-REF(C,1))/REF(C,1)*100,0,5) ,5)=5;
BR2:=ABS((EMA13-EMA34)+(EMA34-EMA55))/C<0.2;
BR3:=C>EMA55 AND (REF(C,1)<REF(EMA55,1) OR REF(C,2)<REF(EMA55,2) OR REF(C,3)<REF(EMA55,3) OR REF
(C,4)<REF(EMA55,4) OR REF(C,5)<REF(EMA55,5));
蚂蚁上树:BR1 AND BR2 AND BR3;
---------------------------
{红衣侠女选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
EMA120:=EMA(C,120);
CR1:=(C-REF(C,1))/REF(C,1)*100>0.5;
CR2:=V>MA(V,5)*0.6;
CR3:=COUNT(CROSS(EMA13,EMA55),3)=1;
CR4:=ABS(EMA34-EMA55)/EMA55<0.03;
CR5:=EMA55<=EMA120 AND EMA55>=REF(EMA55,1);
红衣侠女:FILTER(CR1 AND CR2 AND CR3 AND CR4 AND CR5,2);
--------------------------
{黑客点击选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
DR1:=EMA13>EMA34 AND EMA34<EMA55;
DR2:=BARSLAST(CROSS(C,EMA55) );
DR3:=H=HHV(H,DR2);
DR4:=BARSLAST(DR3);
DR5:=COUNT(O>C AND C<REF(C,1) AND C>EMA55 AND BETWEEN((C-EMA55)/EMA55,0,0.02),DR4)=1;
DR6:=C>REF(C,1) ;
DR7:=DR1 AND DR5 AND DR6 ;
黑客点击:DR7 AND FILTER(DR7,10);
--------------------------
{均线互换选股}
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
均线互换:BARSLAST(REF(CROSS(EMA55,EMA34),1)) AND CROSS(EMA34,EMA55);
--------------------------
{梅开二度选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
梅开二度:BARSLAST(REF(CROSS(EMA34,EMA13),1)) AND CROSS(EMA13,EMA34);
---------------------------------------
{三线推进选股}
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
HR2:=EMA13>=REF(EMA13,3) AND EMA34>=REF(EMA34,1) AND EMA55>=REF(EMA55,1) AND CROSS(C,EMA13) AND
CROSS(C,EMA34) AND CROSS(C,EMA55);
三线推进:(HR2 AND FILTER(HR2,10));

请将指标公式改成选股公式

‘黑客点击’如下:
----------
EMA13:=EMA(C,13);
EMA34:=EMA(C,34);
EMA55:=EMA(C,55);
DR1:=EMA13>EMA34 AND EMA34 ;
DR2:=BARSLAST(CROSS(C,EMA55) );
DR3:=H=HHV(H,DR2);
DR4:=BARSLAST(DR3);
DR5:=COUNT(O>C AND C>EMA55 AND BETWEEN((C-EMA55)/EMA55,0,0.02),DR4)=1;
DR6:=C>REF(C,1) ;
DR7:= DR1 AND DR5 AND DR6 ;
DR8:DR7 AND FILTER(DR7 ,10);

通信达选股器怎么用?

给你举2个例子,你会用这两个了,其它的就会触类旁通。
例子1:依次点击功能/选股器/条件选股/,再最上面的下拉条中找到/出水芙蓉,点击/加入条件,选日线,勾选历史阶段选股,将前后日期都设定为你的选股当日,点击/执行选股即可。就用/出水芙蓉挺好。
例子2:自编的选股公式如何使用
我的操作方式是
创建公式:在公式管理器中新建,复制粘贴,创建公式
选股:选股器-综合选股-用户条件-指标选股-其他类型-找到刚创建的选股公式
以下是两个网上找的选股公式
公式一:
{底背离}
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
B1:=REF(C,A1+1)>C AND REF(DIFF,A1+1)<DIFF AND CROSS(DIFF,DEA);
A2:=BARSLAST(REF(CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3)),1));
B2:=REF(C,A2+1)>C AND REF("KDJ.K"(9,3,3),A2+1)<"KDJ.K"(9,3,3) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));
A3:=BARSLAST(REF(CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24)),1));
B3:=REF(C,A3+1)>C AND REF("RSI.RSI1"(6,12,24),A3+1)<"RSI.RSI1"(6,12,24) AND CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24));
底背离:B1>0 OR B2>0 OR B3>0;
公式二:
DIFF:EMA(DCLOSE,12)-EMA(DCLOSE,26);
DEA:EMA(DIFF,9),COLORFFFF00;
MACD:(DIFF-DEA)*2;
STICKLINE(MACD>=0 AND MACD>=REF(MACD,1),0,MACD,1,0),COLORRED;
STICKLINE(MACD>=0 AND MACD<=REF(MACD,1),0,MACD,1,0),COLORGREEN;
STICKLINE(MACD<=0 AND MACD>=REF(MACD,1),0,MACD,1,0),COLORFF00FF;
STICKLINE(MACD<=0 AND MACD<=REF(MACD,1),0,MACD,1,0),COLOR00FFFF;
多转空:=((((LLV(MACD,4)>0) AND (MACD<REF(MACD,1))) AND (REF(MACD,1)>REF(MACD,2))) AND (REF(MACD,2)>REF(MACD,3)));
空转多:=((((HHV(MACD,4)<0) AND (MACD>REF(MACD,1))) AND (REF(MACD,1)<REF(MACD,2))) AND (REF(MACD,2)<REF(MACD,3)));
DRAWICON(多转空,MACD,2);
DRAWICON(空转多,MACD,1);
低位金叉:=CROSS(DIFF,DEA) AND DIFF<-0.1;
DRAWTEXT(低位金叉,DEA,' 低位金叉'),COLORFF00FF;
{STICKLINE(低位金叉,0,0.3,8,0),COLORYELLOW;
DRAWICON(低位金叉,0.3,1)};
JCCOUNT:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
二次金叉:=CROSS(DIFF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1;
STICKLINE(二次金叉,0,0.2,2,0),COLORFF00FF;
DRAWTEXT(二次金叉,DEA*1.06,'二次金叉'),COLORRED;
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIFF>REF(DIFF,A1+1) AND CROSS(DIFF,DEA);
{STICKLINE(底背离,0.5,0.8,2,0),COLORRED};
DRAWLINE(A1=0,DEA,底背离,DEA,0),COLORRED,LINETHICK3;
A2:=BARSLAST(REF(CROSS(DEA,DIFF),1));
顶背离:=REF(CLOSE,A2+1)<CLOSE AND REF(DIFF,A2+1)>DIFF AND CROSS(DEA,DIFF);
DRAWLINE(A2=0,DEA,顶背离,DEA,0),COLORBLUE,LINETHICK3;

通达信自编的选股公式如何使用

要改成选股公式,只能一条输出,其他都要加上等号.
公式一是可以的.
公式二要改一下.
--------------------
SHORT:=12;
LONG:=26;
MID:=9;
DIF:=EMA(CLOSE,SHORT)-EMA(CLOSE,LONG);
DEA:=EMA(DIF,MID);
MACD:=(DIF-DEA)*2;
选股:DIF<0 AND DEA<0 AND CROSS(DIF,DEA);{低位金叉选股}
----------------------------
选股公式编到条件选股---其他类型;